From 019a0cbd01e59b8ae513988678d082c6d34b4b6e Mon Sep 17 00:00:00 2001
From: Philippe Schenker <philippe.schenker@toradex.com>
Date: Fri, 15 May 2020 17:18:55 +0200
Subject: recipes-connectivity: add hostapd-example package

This will add an example hostapd package that will contain all necessary
files to just "enable" an acces-point on a demo image.

Relates-to: ELB-1303
Signed-off-by: Philippe Schenker <philippe.schenker@toradex.com>
(cherry picked from commit 7873d287300c204c594bc46429bca066cbd68bea)
---
 .../hostapd-example/hostapd-example.bb             | 37 ++++++++++++++++++++++
 1 file changed, 37 insertions(+)
 create mode 100644 recipes-connectivity/hostapd-example/hostapd-example.bb

(limited to 'recipes-connectivity/hostapd-example/hostapd-example.bb')

diff --git a/recipes-connectivity/hostapd-example/hostapd-example.bb b/recipes-connectivity/hostapd-example/hostapd-example.bb
new file mode 100644
index 0000000..dc0b9db
--- /dev/null
+++ b/recipes-connectivity/hostapd-example/hostapd-example.bb
@@ -0,0 +1,37 @@
+SUMMARY = "Deployment of example files to run hostapd on Toradex demo images"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/MIT;md5=0835ade698e0bcf8506ecda2f7b4f302"
+
+FILESEXTRAPATHS_prepend := "${THISDIR}/${PN}:"
+
+RDEPENDS_${PN} = "hostapd"
+
+S = "${WORKDIR}"
+
+SRC_URI = " \
+    file://enable-wifi.service \
+    file://hostapd-example.service \
+    file://hostapd-example.network \
+    file://hostapd-tdx-demo-img.conf \
+"
+
+inherit allarch systemd
+
+SYSTEMD_SERVICE_${PN} = "hostapd-example.service"
+SYSTEMD_AUTO_ENABLE_${PN} = "disable"
+
+do_install() {
+    install -d ${D}${systemd_unitdir}/system/ ${D}${systemd_unitdir}/network/ ${D}${sysconfdir}/
+    install -m 0644 enable-wifi.service ${D}${systemd_unitdir}/system/
+    install -m 0644 hostapd-example.network ${D}${systemd_unitdir}/network/
+    install -m 0644 hostapd-example.service ${D}${systemd_unitdir}/system/
+    install -m 0644 hostapd-tdx-demo-img.conf ${D}${sysconfdir}/
+    sed -i -e 's,@SBINDIR@,${sbindir},g' -e 's,@SYSCONFDIR@,${sysconfdir},g' ${D}${systemd_unitdir}/system/hostapd-example.service
+}
+
+FILES_${PN} += " \
+    ${systemd_unitdir}/system/* \
+    ${systemd_unitdir}/network/hostapd-example.network \
+    ${sysconfdir}/hostapd-tdx-demo-img.conf \
+"
+
-- 
cgit v1.2.3