1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
SUMMARY = "Bluetooth Audio ALSA Backend"
HOMEPAGE = "https://github.com/Arkq/bluez-alsa"
SECTION = "libs"
LICENSE = "MIT"
LIC_FILES_CHKSUM = "file://LICENSE;md5=72d868d66bdd5bf51fe67734431de057"
SRC_URI = "git://github.com/Arkq/bluez-alsa.git;protocol=https;branch=master"
SRCREV = "c9e122547b2ba65ccc16d972a66d2d56ca2f2fe5"
PV = "3.1.0+git${SRCPV}"
S = "${WORKDIR}/git"
DEPENDS += "alsa-lib bluez5 glib-2.0 sbc"
PACKAGECONFIG ??= "aplay cli hcitop ${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)}"
PACKAGECONFIG[a2dpconf] = "--enable-a2dpconf,--disable-a2dpconf"
PACKAGECONFIG[aac] = "--enable-aac,--disable-aac"
PACKAGECONFIG[aplay] = "--enable-aplay,--disable-aplay"
PACKAGECONFIG[aptx] = "--enable-aptx,--disable-aptx"
PACKAGECONFIG[cli] = "--enable-cli,--disable-cli"
PACKAGECONFIG[coverage] = "--with-coverage,--without-coverage,,lcov"
PACKAGECONFIG[debug] = "--enable-debug,--disable-debug"
PACKAGECONFIG[debug-time] = "--enable-debug-time,--disable-debug-time"
PACKAGECONFIG[faststream] = "--enable-faststream,--disable-faststream"
PACKAGECONFIG[hcitop] = "--enable-hcitop,--disable-hcitop,libbsd ncurses"
PACKAGECONFIG[libunwind] = "--with-libunwind,--without-libunwind,libunwind"
PACKAGECONFIG[mp3lame] = "--enable-mp3lame,--disable-mp3lame,lame"
PACKAGECONFIG[mpg123] = "--enable-mpg123,--disable-mpg123,mpg123,mpg123"
PACKAGECONFIG[ofono] = "--enable-ofono,--disable-ofono,ofono"
PACKAGECONFIG[payloadcheck] = "--enable-payloadcheck,--disable-payloadcheck"
PACKAGECONFIG[rfcomm] = "--enable-rfcomm,--disable-rfcomm"
PACKAGECONFIG[systemd] = "--enable-systemd --with-systemdsystemunitdir=${systemd_system_unitdir},--disable-systemd,systemd dbus"
PACKAGECONFIG[upower] = "--enable-upower,--disable-upower,,upower"
inherit autotools pkgconfig systemd
PACKAGE_BEFORE_PN = "${PN}-aplay"
RRECOMMENDS_${PN} = "${PN}-aplay"
FILES_${PN}-aplay = "${bindir}/bluealsa-aplay"
FILES_${PN} += "${libdir}/alsa-lib/*"
SYSTEMD_PACKAGES += "${PN}-aplay"
SYSTEMD_SERVICE_${PN} = "bluealsa.service"
SYSTEMD_SERVICE_${PN}-aplay = "bluealsa-aplay.service"
SYSTEMD_AUTO_ENABLE_${PN}-aplay = "disable"
# Choose bluez-alsa profiles to be used at runtime
# Supported profiles: a2dp-source a2dp-sink hfp-hf hfp-ag hsp-hs hsp-ag hfp-ofono
# Enable output profiles by default
BLUEZ_ALSA_OPTS ?= "-p a2dp-source -p a2dp-sink -p hfp-ag -p hsp-ag"
do_install_append () {
# OE specific, it's bluetooth.service being used instead of bluez.service
sed -i -e 's#After=bluez.service#After=bluetooth.service#' ${D}${systemd_system_unitdir}/bluealsa.service
# Set profiles
sed -i -e 's#ExecStart=.*$#ExecStart=${bindir}/bluealsa ${BLUEZ_ALSA_OPTS}#' ${D}${systemd_system_unitdir}/bluealsa.service
}
|
