hostname: generate a uniqe hostname on boot

This will generate a hostname based on machine name and serial number.
(E.g. colibri-imx7-031111777)
If serial number is not found it will say "no-serial-number" in host
name.
If machine is not supported hostname will include "unsupported-device"
string.
If /dev/device-tree does not exist it will say "recovery-mode"
as it assumes its in recovery mode of Toradex Easy Installer

To prevent openembedded from creating /etc/hostname file
add hostname_pn-base-files = "" to configration

Related-to: TEI-100, ELB-1322
Signed-off-by: Luka Pivk <luka.pivk@toradex.com>

1 files changed, 30 insertions, 0 deletions

diff --git a/recipes-core/set-hostname/set-hostname_1.0.bb b/recipes-core/set-hostname/set-hostname_1.0.bb
new file mode 100644
index 0000000..15fa66b
--- /dev/null
+++ b/recipes-core/set-hostname/set-hostname_1.0.bb
@@ -0,0 +1,30 @@
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/MIT;md5=0835ade698e0bcf8506ecda2f7b4f302"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+inherit systemd
+
+SRC_URI += " \
+    file://sethostname \
+    file://set-hostname.service \
+"
+
+FILES_${PN} = " \
+    ${bindir} \
+    ${systemd_system_unitdir} \
+"
+
+SYSTEMD_SERVICE_${PN} = " \
+    set-hostname.service \
+"
+
+do_install () {
+    install -d ${D}${bindir}
+    install -m 0755 ${WORKDIR}/sethostname ${D}${bindir}
+    sed -i "s/@@MACHINE@@/${MACHINE}/g" ${D}${bindir}/sethostname
+    if ${@bb.utils.contains('DISTRO_FEATURES','systemd','true','false',d)}; then
+        install -d ${D}${systemd_system_unitdir}
+        install -m 0644 ${WORKDIR}/set-hostname.service ${D}${systemd_system_unitdir}
+    fi
+}