imx-sc-firmware: add full recipe for imx-sc-firmware

In order to make git hash bumping work with the imx-sc-firmware we need
to have our own recipe in our layer. This also has the advantage that
the recipe name reflects the actual package version (PV) again. Use
imx-sc-firmware-toradex to make sure we do not interfere with the NXP
provided variant.

Make sure our machines pick imx-sc-firmware-toradex by setting
PREFERRED_PROVIDER accordingly.

Related-to: AUT-355
Signed-off-by: Stefan Agner <stefan.agner@toradex.com>

2 files changed, 46 insertions, 18 deletions

diff --git a/recipes-bsp/imx-sc-firmware/imx-sc-firmware-toradex_1.5.1.bb b/recipes-bsp/imx-sc-firmware/imx-sc-firmware-toradex_1.5.1.bb
new file mode 100644
index 0000000..9c08809
--- /dev/null
+++ b/recipes-bsp/imx-sc-firmware/imx-sc-firmware-toradex_1.5.1.bb
@@ -0,0 +1,46 @@
+# Copyright (C) 2016 Freescale Semiconductor
+# Copyright (C) 2017-2019 NXP
+# Copyright (C) 2020 Toradex
+
+DESCRIPTION = "i.MX System Controller Firmware for Toradex hardware"
+LICENSE = "Proprietary"
+LIC_FILES_CHKSUM = "file://COPYING;md5=94c5a3fc041e195df67fde3979a5e14e"
+SECTION = "BSP"
+
+inherit deploy
+
+SRC_URI = "git://github.com/toradex/i.MX-System-Controller-Firmware.git;branch=master;protocol=https;fsl-eula=true"
+
+SRCREV = "1f184f12405d681d23b77cf5bac66110b9d34ddf"
+SRCREV_use-head-next = "${AUTOREV}"
+
+S = "${WORKDIR}/git"
+
+PROVIDES = "imx-sc-firmware"
+RREPLACES_${PN} = "imx-sc-firmware"
+RPROVIDES_${PN} = "imx-sc-firmware"
+RCONFLICTS_${PN} = "imx-sc-firmware"
+
+BOARD_TYPE ?= "unknown"
+SC_FIRMWARE_NAME_mx8qm = "mx8qm-${BOARD_TYPE}-scfw-tcm.bin"
+SC_FIRMWARE_NAME_mx8qxp = "mx8qx-${BOARD_TYPE}-scfw-tcm.bin"
+symlink_name = "scfw_tcm.bin"
+
+BOOT_TOOLS = "imx-boot-tools"
+
+do_compile[noexec] = "1"
+
+do_install[noexec] = "1"
+
+do_deploy() {
+    install -Dm 0644 ${S}/src/scfw_export_*/build_*/${SC_FIRMWARE_NAME} ${DEPLOYDIR}/${BOOT_TOOLS}/${SC_FIRMWARE_NAME}
+    ln -sf ${SC_FIRMWARE_NAME} ${DEPLOYDIR}/${BOOT_TOOLS}/${symlink_name}
+}
+addtask deploy after do_install
+
+INHIBIT_PACKAGE_STRIP = "1"
+INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+COMPATIBLE_MACHINE = "(apalis-imx8.*|colibri-imx8.*)"
+
diff --git a/recipes-bsp/imx-sc-firmware/imx-sc-firmware_%.bbappend b/recipes-bsp/imx-sc-firmware/imx-sc-firmware_%.bbappend
deleted file mode 100644
index 389ebf3..0000000
--- a/recipes-bsp/imx-sc-firmware/imx-sc-firmware_%.bbappend
+++ /dev/null
@@ -1,18 +0,0 @@
-# get additional scfw binaries provided in:
-SCFW_TDX_SRC ?= "git://github.com/toradex/i.MX-System-Controller-Firmware.git"
-
-SRC_URI += "${SCFW_TDX_SRC};branch=master;protocol=https;fsl-eula=true"
-
-SRCREV = "1f184f12405d681d23b77cf5bac66110b9d34ddf"
-SRCREV_use-head-next = "${AUTOREV}"
-
-do_patch[prefuncs] += "do_cp_scfw"
-do_cp_scfw () {
-	cp ${WORKDIR}/git/src/scfw_export_*/build_*/*-scfw-tcm.bin ${S}/
-}
-
-# get the matching SCFW for NXP's boards for the 5.4.24-2.1.0 BSP
-PV = "1.5.0"
-SRC_URI[md5sum] = "e939f40ca655afbdedabfae73863e6da"
-SRC_URI[sha256sum] = "18ef3717180ef034c1a3418d7342803f2727e4e09531e0a5db13e6f5244f2058"
-LIC_FILES_CHKSUM = "file://COPYING;md5=228c72f2a91452b8a03c4cab30f30ef9"