firmware-imx: update to 8.8

From NXP BSP 5.4.24-2.1.0.

Related-to: ELB-2758
Signed-off-by: Max Krummenacher <max.krummenacher@toradex.com>

7 files changed, 23 insertions, 136 deletions

diff --git a/recipes-bsp/firmware-imx/firmware-imx-8.4.1.inc b/recipes-bsp/firmware-imx/firmware-imx-8.4.1.inc
deleted file mode 100644
index a2fa611..0000000
--- a/recipes-bsp/firmware-imx/firmware-imx-8.4.1.inc
+++ /dev/null
@@ -1,17 +0,0 @@
-# Copyright (C) 2012-2016 Freescale Semiconductor
-# Copyright 2017-2018 NXP
-# Copyright (C) 2018 O.S. Systems Software LTDA.
-SECTION = "base"
-LICENSE = "Proprietary"
-LIC_FILES_CHKSUM = "file://COPYING;md5=fd4b227530cd88a82af6a5982cfb724d"
-
-SRC_URI = " \
-    ${FSL_MIRROR}/firmware-imx-${PV}.bin;fsl-eula=true \
-"
-
-SRC_URI[md5sum] = "70bdefdd7fb58f782237acf4c648f5cd"
-SRC_URI[sha256sum] = "f04b2deb4f126e6b6cd4460462292acd72183b9f799e3b873fb390ff0f18eb55"
-
-S = "${WORKDIR}/firmware-imx-${PV}"
-
-inherit fsl-eula-unpack
diff --git a/recipes-bsp/firmware-imx/firmware-imx-8_8.4.1.bb b/recipes-bsp/firmware-imx/firmware-imx-8_8.4.1.bb
deleted file mode 100644
index 64fa288..0000000
--- a/recipes-bsp/firmware-imx/firmware-imx-8_8.4.1.bb
+++ /dev/null
@@ -1,23 +0,0 @@
-# Copyright 2018 NXP
-SUMMARY = "Freescale i.MX firmware for 8 family"
-DESCRIPTION = "Freescale i.MX firmware for 8 family"
-
-require firmware-imx-${PV}.inc
-
-inherit deploy
-
-do_install[noexec] = "1"
-
-do_deploy() {
-    # Cadence HDMI
-    install -m 0644 ${S}/firmware/hdmi/cadence/hdmitxfw.bin ${DEPLOYDIR}
-    install -m 0644 ${S}/firmware/hdmi/cadence/hdmirxfw.bin ${DEPLOYDIR}
-    install -m 0644 ${S}/firmware/hdmi/cadence/dpfw.bin ${DEPLOYDIR}
-}
-addtask deploy after do_install before do_build
-
-PACKAGE_ARCH = "${MACHINE_SOCARCH}"
-
-COMPATIBLE_MACHINE      = "(mx8)"
-COMPATIBLE_MACHINE_mx8m = "(^$)"
-COMPATIBLE_MACHINE_mx8x = "(^$)"
diff --git a/recipes-bsp/firmware-imx/firmware-imx-8_8.5.bbappend b/recipes-bsp/firmware-imx/firmware-imx-8_8.5.bbappend
new file mode 100644
index 0000000..6aa737c
--- /dev/null
+++ b/recipes-bsp/firmware-imx/firmware-imx-8_8.5.bbappend
@@ -0,0 +1,4 @@
+PV = "8.8"
+LIC_FILES_CHKSUM = "file://COPYING;md5=228c72f2a91452b8a03c4cab30f30ef9"
+SRC_URI[md5sum] = "eabb27d28bba375a9f14d6306c07af5f"
+SRC_URI[sha256sum] = "5ca1f8b6e6b191594d17ac7b51c38cdbc2ff808d15568ab4b0bbeb5dc6c621f6"
diff --git a/recipes-bsp/firmware-imx/firmware-imx-8m_8.4.1.bb b/recipes-bsp/firmware-imx/firmware-imx-8m_8.4.1.bb
deleted file mode 100644
index a605d22..0000000
--- a/recipes-bsp/firmware-imx/firmware-imx-8m_8.4.1.bb
+++ /dev/null
@@ -1,24 +0,0 @@
-# Copyright 2018 NXP
-SUMMARY = "Freescale i.MX firmware for 8M and 8M Mini family"
-DESCRIPTION = "Freescale i.MX firmware for 8M and 8M Mini family"
-
-require firmware-imx-${PV}.inc
-
-inherit deploy
-
-do_install[noexec] = "1"
-
-do_deploy() {
-    # Synopsys DDR
-    for ddr_firmware in ${DDR_FIRMWARE_NAME}; do
-        install -m 0644 ${S}/firmware/ddr/synopsys/${ddr_firmware} ${DEPLOYDIR}
-    done
-    # Cadence DP and HDMI
-    install -m 0644 ${S}/firmware/hdmi/cadence/signed_dp_imx8m.bin ${DEPLOYDIR}
-    install -m 0644 ${S}/firmware/hdmi/cadence/signed_hdmi_imx8m.bin ${DEPLOYDIR}
-}
-addtask deploy after do_install before do_build
-
-PACKAGE_ARCH = "${MACHINE_SOCARCH}"
-
-COMPATIBLE_MACHINE = "(mx8m)"
diff --git a/recipes-bsp/firmware-imx/firmware-imx-8m_8.5.bbappend b/recipes-bsp/firmware-imx/firmware-imx-8m_8.5.bbappend
new file mode 100644
index 0000000..6aa737c
--- /dev/null
+++ b/recipes-bsp/firmware-imx/firmware-imx-8m_8.5.bbappend
@@ -0,0 +1,4 @@
+PV = "8.8"
+LIC_FILES_CHKSUM = "file://COPYING;md5=228c72f2a91452b8a03c4cab30f30ef9"
+SRC_URI[md5sum] = "eabb27d28bba375a9f14d6306c07af5f"
+SRC_URI[sha256sum] = "5ca1f8b6e6b191594d17ac7b51c38cdbc2ff808d15568ab4b0bbeb5dc6c621f6"
diff --git a/recipes-bsp/firmware-imx/firmware-imx_8.4.1.bb b/recipes-bsp/firmware-imx/firmware-imx_8.4.1.bb
deleted file mode 100644
index 4d4b479..0000000
--- a/recipes-bsp/firmware-imx/firmware-imx_8.4.1.bb
+++ /dev/null
@@ -1,72 +0,0 @@
-# Copyright (C) 2012-2016 Freescale Semiconductor
-# Copyright 2017-2018 NXP
-# Copyright (C) 2018 O.S. Systems Software LTDA.
-SUMMARY = "Freescale i.MX firmware"
-DESCRIPTION = "Freescale i.MX firmware such as for the VPU"
-
-require firmware-imx-${PV}.inc
-
-PE = "1"
-
-inherit allarch
-
-do_install() {
-    install -d ${D}${base_libdir}/firmware/imx
-    install -d ${D}${sysconfdir}/firmware
-
-    cd firmware
-    for d in *; do
-        case $d in
-        ddr|hdmi|seco)
-            # These folders are for i.MX 8 and are included in the boot image via imx-boot
-            bbnote Excluding folder $d
-            ;;
-        *)
-            cp -rfv $d ${D}${base_libdir}/firmware
-            ;;
-        esac
-    done
-    cd -
-
-    #the sdma firmware is expected in ${D}${base_libdir}/firmware/imx/sdma
-    mv ${D}${base_libdir}/firmware/sdma ${D}${base_libdir}/firmware/imx/sdma
-
-    mv ${D}${base_libdir}/firmware/epdc/ ${D}${base_libdir}/firmware/imx/epdc/
-    mv ${D}${base_libdir}/firmware/imx/epdc/epdc_ED060XH2C1.fw.nonrestricted ${D}${base_libdir}/firmware/imx/epdc/epdc_ED060XH2C1.fw
-
-    mv ${D}${base_libdir}/firmware/easrc/ ${D}${base_libdir}/firmware/imx/easrc/
-
-    find ${D}${base_libdir}/firmware -type f -exec chmod 644 '{}' ';'
-    find ${D}${base_libdir}/firmware -type f -exec chown root:root '{}' ';'
-
-    # Remove files not going to be installed
-    find ${D}${base_libdir}/firmware/ -name '*.mk' -exec rm '{}' ';'
-}
-
-python populate_packages_prepend() {
-    vpudir = bb.data.expand('${base_libdir}/firmware/vpu', d)
-    do_split_packages(d, vpudir, '^vpu_fw_([^_]*).*\.bin',
-                      output_pattern='firmware-imx-vpu-%s',
-                      description='Freescale IMX Firmware %s',
-                      extra_depends='',
-                      prepend=True)
-
-    sdmadir = bb.data.expand('${base_libdir}/firmware/imx/sdma', d)
-    do_split_packages(d, sdmadir, '^sdma-([^-]*).*\.bin',
-                      output_pattern='firmware-imx-sdma-%s',
-                      description='Freescale IMX Firmware %s',
-                      extra_depends='',
-                      prepend=True)
-}
-
-ALLOW_EMPTY_${PN} = "1"
-
-PACKAGES_DYNAMIC = "${PN}-vpu-* ${PN}-sdma-*"
-
-PACKAGES =+ "${PN}-easrc ${PN}-epdc ${PN}-scfw"
-
-FILES_${PN}-epdc = "${base_libdir}/firmware/imx/epdc/"
-FILES_${PN}-scfw = "${base_libdir}/firmware/scfw/"
-FILES_${PN}-easrc = "${base_libdir}/firmware/imx/easrc/"
-
-COMPATIBLE_MACHINE = "(imx)"
diff --git a/recipes-bsp/firmware-imx/firmware-imx_8.5.bbappend b/recipes-bsp/firmware-imx/firmware-imx_8.5.bbappend
new file mode 100644
index 0000000..5a55881
--- /dev/null
+++ b/recipes-bsp/firmware-imx/firmware-imx_8.5.bbappend
@@ -0,0 +1,15 @@
+PV = "8.8"
+LIC_FILES_CHKSUM = "file://COPYING;md5=228c72f2a91452b8a03c4cab30f30ef9"
+SRC_URI[md5sum] = "eabb27d28bba375a9f14d6306c07af5f"
+SRC_URI[sha256sum] = "5ca1f8b6e6b191594d17ac7b51c38cdbc2ff808d15568ab4b0bbeb5dc6c621f6"
+
+PACKAGES =+ "${PN}-xcvr ${PN}-xuvi"
+
+do_install_append () {
+    mv ${D}${base_libdir}/firmware/xcvr/ ${D}${base_libdir}/firmware/imx/xcvr/
+
+    mv ${D}${base_libdir}/firmware/xuvi/ ${D}${base_libdir}/firmware/imx/xuvi/
+}
+
+FILES_${PN}-xcvr = "${base_libdir}/firmware/imx/xcvr/"
+FILES_${PN}-xuvi = "${base_libdir}/firmware/imx/xuvi/"